feat(&minecraft): move minecraft to nix-minecraft repo

flake.nix

@@ -45,6 +45,11 @@
     # # --- Powercord
     powercord-setup.url = "path:/etc/nixos/subflakes/powercord";
     powercord-setup.inputs.nixpkgs.follows = "latest";
+
+    # # --- Minecraft
+    nix-minecraft.url = "github:Infinidoge/nix-minecraft";
+    nix-minecraft.inputs.nixpkgs.follows = "nixos";
+    nix-minecraft.inputs.digga.follows = "digga";
   };
 
   outputs =
@@ -73,6 +78,7 @@
 
               # --- Application-Specific Overlays
               inputs.powercord-setup.overlay
+              inputs.nix-minecraft.overlay
             ];
           };
           stable = { };
@@ -108,6 +114,7 @@
 
               inputs.impermanence.nixosModules.impermanence
               inputs.quick-nix-registry.nixosModules.local-registry
+              inputs.nix-minecraft.nixosModules.minecraft-servers
 
               ./secrets
             ];

modules/functionality/minecraft-servers.nix

@@ -1,185 +0,0 @@
-{ config, lib, pkgs, ... }:
-with lib;
-with lib.hlissner;
-let
-  cfg = config.services.minecraft-servers;
-in
-{
-  options.services.minecraft-servers = {
-    enable = mkBoolOpt false;
-    eula = mkBoolOpt false;
-    openFirewall = mkBoolOpt false;
-    dataDir = mkOpt types.path "/srv/minecraft";
-
-    servers = mkOption {
-      default = { };
-      type = types.attrsOf (types.submodule {
-        options = {
-          enable = mkBoolOpt false;
-
-          autoStart = mkBoolOpt true;
-
-          openFirewall = mkBoolOpt cfg.openFirewall;
-
-          restart = mkOpt types.str "always";
-
-          whitelist = mkOption {
-            type =
-              let
-                minecraftUUID = types.strMatching
-                  "[0-9a-f]{8}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{12}" // {
-                  description = "Minecraft UUID";
-                };
-              in
-              types.attrsOf minecraftUUID;
-            default = { };
-          };
-
-          serverProperties = mkOpt (with types; attrsOf (oneOf [ bool int str ])) { };
-
-          package = mkOpt types.package pkgs.minecraft-server;
-
-          jvmOpts = mkOpt (types.separatedString " ") "-Xmx2G -Xms1G";
-
-          symlinks = mkOpt (types.attrsOf types.package) { };
-        };
-      });
-    };
-  };
-
-  config = mkIf cfg.enable
-    (
-      let
-        servers = filterAttrs (_: cfg: cfg.enable) cfg.servers;
-      in
-      {
-        users = {
-          users.minecraft = {
-            description = "Minecraft server service user";
-            home = cfg.dataDir;
-            isSystemUser = true;
-            group = "minecraft";
-          };
-          groups.minecraft = { };
-        };
-
-        assertions = [
-          {
-            assertion = cfg.eula;
-            message = "You must agree to Mojangs EULA to run minecraft-servers."
-              + " Read https://account.mojang.com/documents/minecraft_eula and"
-              + " set `services.minecraft-servers.eula` to `true` if you agree.";
-          }
-        ];
-
-        networking.firewall =
-          let
-            toOpen = filterAttrs (_: cfg: cfg.openFirewall) servers;
-            UDPPorts = mapAttrsToList (name: conf: conf.serverProperties.server-port or 25565) toOpen;
-            TCPPorts = concatLists
-              (mapAttrsToList
-                (name: conf: with conf;
-                (optional (serverProperties.enable-rcon or false) (serverProperties."rcon.port" or 25575)) ++
-                (optional (serverProperties.enable-query or false) (serverProperties."query.port" or 25565))
-                )
-                toOpen
-              );
-          in
-          rec {
-            allowedUDPPorts = UDPPorts;
-            allowedTCPPorts = UDPPorts ++ TCPPorts;
-          };
-
-        system.activationScripts.minecraft-server-data-dir.text = ''
-          mkdir -p ${cfg.dataDir}
-          chown minecraft:minecraft ${cfg.dataDir}
-          chmod -R 775 ${cfg.dataDir}
-        '';
-
-        systemd.services = mapAttrs'
-          (name: conf:
-            let
-              serverDir = "${cfg.dataDir}/${name}";
-              tmux = "${getBin pkgs.tmux}/bin/tmux";
-              tmuxSock = "/run/minecraft/${name}.sock";
-
-              startScript = pkgs.writeScript "minecraft-start-${name}" ''
-                #!${pkgs.runtimeShell}
-
-                cd ${serverDir}
-                ${tmux} -S ${tmuxSock} new -d ${conf.package}/bin/minecraft-server ${conf.jvmOpts}
-              '';
-
-              stopScript = pkgs.writeScript "minecraft-stop-${name}" ''
-                #!${pkgs.runtimeShell}
-
-                if ! [ -d "/proc/$1" ]; then
-                  exit 0
-                fi
-
-                ${tmux} -S ${tmuxSock} send-keys stop Enter
-              '';
-            in
-            {
-              name = "minecraft-server-${name}";
-              value = {
-                description = "Minecraft Server ${name}";
-                wantedBy = mkIf conf.autoStart [ "multi-user.target" ];
-                after = [ "network.target" ];
-
-                enable = conf.enable;
-
-                serviceConfig = {
-                  ExecStart = "${startScript}";
-                  ExecStop = "${stopScript} $MAINPID";
-                  Restart = conf.restart;
-                  User = "minecraft";
-                  Type = "forking";
-                  GuessMainPID = true;
-                  RuntimeDirectory = "minecraft";
-                };
-
-                preStart =
-                  let
-                    eula = builtins.toFile "eula.txt" ''
-                      # eula.txt managed by NixOS Configuration
-                      eula=true
-                    '';
-
-                    whitelist = pkgs.writeText "whitelist.json"
-                      (builtins.toJSON
-                        (mapAttrsToList (n: v: { name = n; uuid = v; }) conf.whitelist));
-
-                    serverProperties =
-                      let
-                        cfgToString = v: if builtins.isBool v then boolToString v else toString v;
-                      in
-                      pkgs.writeText "server.properties" (''
-                        # server.properties managed by NixOS configuration
-                      '' + concatStringsSep "\n" (mapAttrsToList
-                        (n: v: "${n}=${cfgToString v}")
-                        conf.serverProperties));
-
-                    mkSymlinks = pkgs.writeShellScript "minecraft-server-${name}-symlinks"
-                      (concatStringsSep "\n"
-                        (mapAttrsToList (n: v: "ln -sf ${v} ${n}") conf.symlinks));
-                  in
-                  ''
-                    mkdir -p ${serverDir}
-                    chmod -R 775 ${serverDir}
-                    cd ${serverDir}
-                    ln -sf ${eula} eula.txt
-                    ln -sf ${whitelist} whitelist.json
-                    cp -f ${serverProperties} server.properties
-                    ${mkSymlinks}
-                  '';
-
-                postStart = ''
-                  ${pkgs.coreutils}/bin/chmod 660 ${tmuxSock}
-                '';
-              };
-            })
-          servers;
-      }
-    );
-}

pkgs/default.nix

@@ -2,8 +2,4 @@ final: prev: {
   # keep sources this first
   sources = prev.callPackage (import ./_sources/generated.nix) { };
   # then, call packages with `final.callPackage`
-
-  fetchModrinthMod = final.callPackage (import ./fabric-mods/fetchModrinthMod.nix);
-
-  fabric-server = final.callPackage (import ./fabric-server) { };
 }

pkgs/fabric-mods/fetchModrinthMod.nix

@@ -1,6 +0,0 @@
-{ stdenv, fetchurl, id, responseHash }:
-let
-  version = (builtins.fromJSON (builtins.readFile (fetchurl { url = "https://api.modrinth.com/v2/version/${id}"; sha256 = responseHash; })));
-  file = (builtins.elemAt version.files 0);
-in
-fetchurl { url = file.url; sha512 = file.hashes.sha512; }

pkgs/fabric-server/default.nix

@@ -1,43 +0,0 @@
-{ callPackage, writeTextFile, writeShellScriptBin, minecraft-server, jre_headless }:
-
-let
-  loader = callPackage ./generate-loader.nix { lock = import ./lock.nix; };
-  log4j = writeTextFile {
-    name = "log4j.xml";
-    text = ''
-      <?xml version="1.0" encoding="UTF-8"?>
-      <Configuration status="WARN" packages="com.mojang.util">
-          <Appenders>
-              <Console name="SysOut" target="SYSTEM_OUT">
-                  <PatternLayout pattern="[%d{HH:mm:ss}] [%t/%level]: %msg%n" />
-              </Console>
-              <Queue name="ServerGuiConsole">
-                  <PatternLayout pattern="[%d{HH:mm:ss} %level]: %msg%n" />
-              </Queue>
-              <RollingRandomAccessFile name="File" fileName="logs/latest.log" filePattern="logs/%d{yyyy-MM-dd}-%i.log.gz">
-                  <PatternLayout pattern="[%d{HH:mm:ss}] [%t/%level]: %msg%n" />
-                  <Policies>
-                      <TimeBasedTriggeringPolicy />
-                      <OnStartupTriggeringPolicy />
-                  </Policies>
-                  <DefaultRolloverStrategy max="1000"/>
-              </RollingRandomAccessFile>
-          </Appenders>
-          <Loggers>
-              <Root level="info">
-                  <filters>
-                      <MarkerFilter marker="NETWORK_PACKETS" onMatch="DENY" onMismatch="NEUTRAL" />
-                  </filters>
-                  <AppenderRef ref="SysOut"/>
-                  <AppenderRef ref="File"/>
-                  <AppenderRef ref="ServerGuiConsole"/>
-              </Root>
-          </Loggers>
-      </Configuration>
-    '';
-  };
-in
-# Taken from https://github.com/FabricMC/fabric-installer/issues/50#issuecomment-1013444858
-writeShellScriptBin "minecraft-server" ''
-  echo "serverJar=${minecraft-server}/lib/minecraft/server.jar" >> fabric-server-launcher.properties
-  exec ${jre_headless}/bin/java -Dlog4j.configurationFile=${log4j} $@ -jar ${loader} nogui''

pkgs/fabric-server/generate-loader.nix

@@ -1,36 +0,0 @@
-{ lib, fetchurl, stdenv, unzip, zip, jre_headless, lock }:
-
-let
-  libraries = lib.forEach lock.libraries fetchurl;
-in
-stdenv.mkDerivation {
-  name = "fabric-server-launch.jar";
-  nativeBuildInputs = [ unzip zip jre_headless ];
-
-  libraries = libraries;
-
-  buildPhase = ''
-    for i in $libraries; do
-      unzip -o $i
-    done
-
-    cat > META-INF/MANIFEST.MF << EOF
-    Manifest-Version: 1.0
-    Main-Class: net.fabricmc.loader.impl.launch.server.FabricServerLauncher
-    Name: org/objectweb/asm/
-    Implementation-Version: 9.2
-    EOF
-
-    cat > fabric-server-launch.properties << EOF
-    launch.mainClass=${lock.mainClass}
-    EOF
-  '';
-
-  installPhase = ''
-    jar cmvf META-INF/MANIFEST.MF "server.jar" .
-    zip -d server.jar 'META-INF/*.SF' 'META-INF/*.RSA' 'META-INF/*.DSA'
-    cp server.jar "$out"
-  '';
-
-  phases = [ "buildPhase" "installPhase" ];
-}

pkgs/fabric-server/generate-lock-nix.bash

@@ -1,22 +0,0 @@
-#!/usr/bin/env nix-shell
-#!nix-shell -i bash -p bash curl jq
-curl https://meta.fabricmc.net/v2/versions/loader/$1/0.13.3/server/json \
-| jq -r '
-  .mainClass,
-  (.libraries[]
-  | .url as $url
-  | .name | split(":") as [$dir, $name, $version]
-  |"\($name)-\($version).zip|\($url)\($dir|sub("\\.";"/";"g"))/\($name)/\($version)/\($name)-\($version).jar"
-  )' \
-| {
-    echo '{'
-    read mainClass;
-    echo "  mainClass = \"$mainClass\";"
-    echo "  libraries = ["
-    while IFS="|" read name url; do
-        hash=$(nix-prefetch-url $url);
-        echo "    { name = \"$name\"; sha256 = \"$hash\"; url = \"$url\"; }"
-    done
-    echo "  ];"
-    echo '}'
-}

pkgs/fabric-server/lock.nix

@@ -1,16 +0,0 @@
-{
-  mainClass = "net.fabricmc.loader.impl.launch.knot.KnotServer";
-  libraries = [
-    { name = "tiny-mappings-parser-0.3.0+build.17.zip"; sha256 = "19kvhxfk5v01f2rvl7j02vqhn3nd2bh5jsgbk44rpzqv9f6074db"; url = "https://maven.fabricmc.net/net/fabricmc/tiny-mappings-parser/0.3.0+build.17/tiny-mappings-parser-0.3.0+build.17.jar"; }
-    { name = "sponge-mixin-0.11.1+mixin.0.8.5.zip"; sha256 = "02n1l9ihsr2qhfdsz05whbpck1q5vj94cdqqz94wc9ndx0abjr31"; url = "https://maven.fabricmc.net/net/fabricmc/sponge-mixin/0.11.1+mixin.0.8.5/sponge-mixin-0.11.1+mixin.0.8.5.jar"; }
-    { name = "tiny-remapper-0.8.1.zip"; sha256 = "06x5lskpiamx8nf1s3z6vf2ii8mmvmzf7b9yyrvzj61vqk4pk96k"; url = "https://maven.fabricmc.net/net/fabricmc/tiny-remapper/0.8.1/tiny-remapper-0.8.1.jar"; }
-    { name = "access-widener-2.1.0.zip"; sha256 = "08llpdl44rgh609b65lbkx88n87f5vj2c66dcn7629xmv20b8xc1"; url = "https://maven.fabricmc.net/net/fabricmc/access-widener/2.1.0/access-widener-2.1.0.jar"; }
-    { name = "asm-9.2.zip"; sha256 = "1xa7kccwmcqcdw1xly6n2frzhk56m8ma9v7h764g73ckf56zxm5r"; url = "https://maven.fabricmc.net/org/ow2/asm/asm/9.2/asm-9.2.jar"; }
-    { name = "asm-analysis-9.2.zip"; sha256 = "1i1kyirizs5sm2v0f06sdz86mbmyn61vjr9d9p8p5h1i2x9bx3w7"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-analysis/9.2/asm-analysis-9.2.jar"; }
-    { name = "asm-commons-9.2.zip"; sha256 = "19p04mr14ahndba65v4krbvf4p5syf8wz0fp5i9bnf5270qyak5y"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-commons/9.2/asm-commons-9.2.jar"; }
-    { name = "asm-tree-9.2.zip"; sha256 = "04g0zb7v65iz4k2m2grdpbv8jjryrzkkw7ww23yfp94i6399pgxa"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-tree/9.2/asm-tree-9.2.jar"; }
-    { name = "asm-util-9.2.zip"; sha256 = "16759v4hh3ijpf4cglrxybz29x2hiylhsa388y09m2mf679kqnzz"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-util/9.2/asm-util-9.2.jar"; }
-    { name = "intermediary-1.18.1.zip"; sha256 = "1rfz2gazvnivn6hlqiyjpiaycz8va87n5czy1p6w3lnrlfggj2i9"; url = "https://maven.fabricmc.net/net/fabricmc/intermediary/1.18.1/intermediary-1.18.1.jar"; }
-    { name = "fabric-loader-0.13.1.zip"; sha256 = "1hmphq8z38p130pwba97f2zi6ryf0rb10bsnf3bd6s1vfia8xiiq"; url = "https://maven.fabricmc.net/net/fabricmc/fabric-loader/0.13.1/fabric-loader-0.13.1.jar"; }
-  ];
-}