From 5147b5dbda0137e242aa2ff5f3f61f453f193c8e Mon Sep 17 00:00:00 2001
From: Infinidoge <infinidoge@inx.moe>
Date: Tue, 8 Feb 2022 16:32:32 -0500
Subject: [PATCH] feat(fabric-server): create fabric-server package

---
 pkgs/default.nix                          |  2 ++
 pkgs/fabric-server/default.nix            | 43 +++++++++++++++++++++++
 pkgs/fabric-server/generate-loader.nix    | 37 +++++++++++++++++++
 pkgs/fabric-server/generate-lock-nix.bash | 22 ++++++++++++
 pkgs/fabric-server/lock.nix               | 16 +++++++++
 5 files changed, 120 insertions(+)
 create mode 100644 pkgs/fabric-server/default.nix
 create mode 100644 pkgs/fabric-server/generate-loader.nix
 create mode 100755 pkgs/fabric-server/generate-lock-nix.bash
 create mode 100644 pkgs/fabric-server/lock.nix

diff --git a/pkgs/default.nix b/pkgs/default.nix
index 924a230..a31bb41 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -2,4 +2,6 @@ final: prev: {
   # keep sources this first
   sources = prev.callPackage (import ./_sources/generated.nix) { };
   # then, call packages with `final.callPackage`
+
+  fabric-server = final.callPackage (import ./fabric-server) { };
 }
diff --git a/pkgs/fabric-server/default.nix b/pkgs/fabric-server/default.nix
new file mode 100644
index 0000000..c2100ad
--- /dev/null
+++ b/pkgs/fabric-server/default.nix
@@ -0,0 +1,43 @@
+{ callPackage, writeTextFile, writeShellScriptBin, minecraft-server, jre_headless }:
+
+let
+  loader = callPackage ./generate-loader.nix { };
+  log4j = writeTextFile {
+    name = "log4j.xml";
+    text = ''
+      <?xml version="1.0" encoding="UTF-8"?>
+      <Configuration status="WARN" packages="com.mojang.util">
+          <Appenders>
+              <Console name="SysOut" target="SYSTEM_OUT">
+                  <PatternLayout pattern="[%d{HH:mm:ss}] [%t/%level]: %msg%n" />
+              </Console>
+              <Queue name="ServerGuiConsole">
+                  <PatternLayout pattern="[%d{HH:mm:ss} %level]: %msg%n" />
+              </Queue>
+              <RollingRandomAccessFile name="File" fileName="logs/latest.log" filePattern="logs/%d{yyyy-MM-dd}-%i.log.gz">
+                  <PatternLayout pattern="[%d{HH:mm:ss}] [%t/%level]: %msg%n" />
+                  <Policies>
+                      <TimeBasedTriggeringPolicy />
+                      <OnStartupTriggeringPolicy />
+                  </Policies>
+                  <DefaultRolloverStrategy max="1000"/>
+              </RollingRandomAccessFile>
+          </Appenders>
+          <Loggers>
+              <Root level="info">
+                  <filters>
+                      <MarkerFilter marker="NETWORK_PACKETS" onMatch="DENY" onMismatch="NEUTRAL" />
+                  </filters>
+                  <AppenderRef ref="SysOut"/>
+                  <AppenderRef ref="File"/>
+                  <AppenderRef ref="ServerGuiConsole"/>
+              </Root>
+          </Loggers>
+      </Configuration>
+    '';
+  };
+in
+# Taken from https://github.com/FabricMC/fabric-installer/issues/50#issuecomment-1013444858
+writeShellScriptBin "minecraft-server" ''
+  echo "serverJar=${minecraft-server}/lib/minecraft/server.jar" >> fabric-server-launcher.properties
+  exec ${jre_headless}/bin/java -Dlog4j.configurationFile=${log4j} $@ -jar ${loader} nogui''
diff --git a/pkgs/fabric-server/generate-loader.nix b/pkgs/fabric-server/generate-loader.nix
new file mode 100644
index 0000000..252f9f7
--- /dev/null
+++ b/pkgs/fabric-server/generate-loader.nix
@@ -0,0 +1,37 @@
+{ lib, fetchurl, stdenv, unzip, zip, jre_headless }:
+
+let
+  lock = import ./lock.nix;
+  libraries = lib.forEach lock.libraries fetchurl;
+in
+stdenv.mkDerivation {
+  name = "fabric-server-launch.jar";
+  nativeBuildInputs = [ unzip zip jre_headless ];
+
+  libraries = libraries;
+
+  buildPhase = ''
+    for i in $libraries; do
+      unzip -o $i
+    done
+
+    cat > META-INF/MANIFEST.MF << EOF
+    Manifest-Version: 1.0
+    Main-Class: net.fabricmc.loader.impl.launch.server.FabricServerLauncher
+    Name: org/objectweb/asm/
+    Implementation-Version: 9.2
+    EOF
+
+    cat > fabric-server-launch.properties << EOF
+    launch.mainClass=net.fabricmc.loader.impl.launch.knot.KnotServer
+    EOF
+  '';
+
+  installPhase = ''
+    jar cmvf META-INF/MANIFEST.MF "server.jar" .
+    zip -d server.jar 'META-INF/*.SF' 'META-INF/*.RSA' 'META-INF/*.DSA'
+    cp server.jar "$out"
+  '';
+
+  phases = [ "buildPhase" "installPhase" ];
+}
diff --git a/pkgs/fabric-server/generate-lock-nix.bash b/pkgs/fabric-server/generate-lock-nix.bash
new file mode 100755
index 0000000..d73d504
--- /dev/null
+++ b/pkgs/fabric-server/generate-lock-nix.bash
@@ -0,0 +1,22 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p bash curl jq
+curl https://meta.fabricmc.net/v2/versions/loader/1.18.1/0.13.1/server/json \
+| jq -r '
+  .mainClass,
+  (.libraries[]
+  | .url as $url
+  | .name | split(":") as [$dir, $name, $version]
+  |"\($name)-\($version).zip|\($url)\($dir|sub("\\.";"/";"g"))/\($name)/\($version)/\($name)-\($version).jar"
+  )' \
+| {
+    echo '{'
+    read mainClass;
+    echo "  mainClass = \"$mainClass\";"
+    echo "  libraries = ["
+    while IFS="|" read name url; do
+        hash=$(nix-prefetch-url $url);
+        echo "    { name = \"$name\"; sha256 = \"$hash\"; url = \"$url\"; }"
+    done
+    echo "  ];"
+    echo '}'
+}
diff --git a/pkgs/fabric-server/lock.nix b/pkgs/fabric-server/lock.nix
new file mode 100644
index 0000000..56ac0f5
--- /dev/null
+++ b/pkgs/fabric-server/lock.nix
@@ -0,0 +1,16 @@
+{
+  mainClass = "net.fabricmc.loader.impl.launch.knot.KnotServer";
+  libraries = [
+    { name = "tiny-mappings-parser-0.3.0+build.17.zip"; sha256 = "19kvhxfk5v01f2rvl7j02vqhn3nd2bh5jsgbk44rpzqv9f6074db"; url = "https://maven.fabricmc.net/net/fabricmc/tiny-mappings-parser/0.3.0+build.17/tiny-mappings-parser-0.3.0+build.17.jar"; }
+    { name = "sponge-mixin-0.11.1+mixin.0.8.5.zip"; sha256 = "02n1l9ihsr2qhfdsz05whbpck1q5vj94cdqqz94wc9ndx0abjr31"; url = "https://maven.fabricmc.net/net/fabricmc/sponge-mixin/0.11.1+mixin.0.8.5/sponge-mixin-0.11.1+mixin.0.8.5.jar"; }
+    { name = "tiny-remapper-0.8.1.zip"; sha256 = "06x5lskpiamx8nf1s3z6vf2ii8mmvmzf7b9yyrvzj61vqk4pk96k"; url = "https://maven.fabricmc.net/net/fabricmc/tiny-remapper/0.8.1/tiny-remapper-0.8.1.jar"; }
+    { name = "access-widener-2.1.0.zip"; sha256 = "08llpdl44rgh609b65lbkx88n87f5vj2c66dcn7629xmv20b8xc1"; url = "https://maven.fabricmc.net/net/fabricmc/access-widener/2.1.0/access-widener-2.1.0.jar"; }
+    { name = "asm-9.2.zip"; sha256 = "1xa7kccwmcqcdw1xly6n2frzhk56m8ma9v7h764g73ckf56zxm5r"; url = "https://maven.fabricmc.net/org/ow2/asm/asm/9.2/asm-9.2.jar"; }
+    { name = "asm-analysis-9.2.zip"; sha256 = "1i1kyirizs5sm2v0f06sdz86mbmyn61vjr9d9p8p5h1i2x9bx3w7"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-analysis/9.2/asm-analysis-9.2.jar"; }
+    { name = "asm-commons-9.2.zip"; sha256 = "19p04mr14ahndba65v4krbvf4p5syf8wz0fp5i9bnf5270qyak5y"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-commons/9.2/asm-commons-9.2.jar"; }
+    { name = "asm-tree-9.2.zip"; sha256 = "04g0zb7v65iz4k2m2grdpbv8jjryrzkkw7ww23yfp94i6399pgxa"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-tree/9.2/asm-tree-9.2.jar"; }
+    { name = "asm-util-9.2.zip"; sha256 = "16759v4hh3ijpf4cglrxybz29x2hiylhsa388y09m2mf679kqnzz"; url = "https://maven.fabricmc.net/org/ow2/asm/asm-util/9.2/asm-util-9.2.jar"; }
+    { name = "intermediary-1.18.1.zip"; sha256 = "1rfz2gazvnivn6hlqiyjpiaycz8va87n5czy1p6w3lnrlfggj2i9"; url = "https://maven.fabricmc.net/net/fabricmc/intermediary/1.18.1/intermediary-1.18.1.jar"; }
+    { name = "fabric-loader-0.13.1.zip"; sha256 = "1hmphq8z38p130pwba97f2zi6ryf0rb10bsnf3bd6s1vfia8xiiq"; url = "https://maven.fabricmc.net/net/fabricmc/fabric-loader/0.13.1/fabric-loader-0.13.1.jar"; }
+  ];
+}